mail.altrad.com/2015.02.mail.altrad.com.tar/mail.altrad.com/TEST/office german/PROPLUS.WW/PROPLSWW.CAB/FL_Compsvcspkg_dll_____X86.3643236F_FC70_11D3_A536_0090278A1BB8/RCDATA/2049

Extensible Markup Language | 2006-10-26 | 11KB | 243 lines

<?xml version="1.0" encoding="UTF-8" ?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0" xmlns:wsdl="http://schemas.xmlsoap.org/wsdl/"
    xmlns:ms="urn:schemas-microsoft-com:xslt" xmlns:s="http://www.w3.org/2001/XMLSchema" exclude-result-prefixes="wsdl ms s">
    <xsl:output method="xml"
        omit-xml-declaration = "yes"/>

    <!--
    =========================================================
    We do use two pass xsl transform to produce pretty HTM out of wsdl
    files. this stylesheet is used at pass 1. It will produce a single XML
    output that will contain all the data the second pass will need to produce the
    HTM. We still does not support all the posible cases that could be expressed
    by wsdl schema. For example messages with multiple parts or tyreferences in the type


    =========================================================
    -->



    <xsl:template match="/">
        <wsdl>
            <definitions>
                <xsl:apply-templates select="/" mode= "collect"/>
            </definitions>
        </wsdl>
    </xsl:template>


    <xsl:template match="wsdl:definitions" mode="collect">

        <!-- walk the imports  -->
        <xsl:for-each  select="wsdl:import">

            <xsl:apply-templates select="document(@location)" mode="collect"/>
        </xsl:for-each>


        <!--
        =========================================================
        colect what we need from service node[s]
        =========================================================
        -->
        <xsl:for-each  select="wsdl:service">
            <service>

                <xsl:attribute name="name">
                    <xsl:value-of select="@name" />
                </xsl:attribute>



                <!-- save the documentation node if any  -->
                <xsl:if test="wsdl:documentation">
                    <documentation>
                        <xsl:value-of select="."/>
                    </documentation>
                </xsl:if>

            </service>
        </xsl:for-each>

        <!--
        =========================================================
        colect what we need from portType node[s]
        =========================================================
        -->
        <xsl:for-each  select="wsdl:portType">
            <portType>

                <xsl:attribute name="name">
                    <xsl:value-of select="@name" />
                </xsl:attribute>


                <!-- collect all the methods -->
                <xsl:for-each   select="wsdl:operation">
                    <operation>
                        <xsl:attribute name="name">
                            <xsl:value-of select="@name" />
                        </xsl:attribute>

                        <!-- for each method we need the message name for the input and output messages
                             (used to build the argument list and return type of the method)
                             as well as content of description node if exist
                        -->

                        <xsl:if test="wsdl:input">
                            <input>
                                <xsl:attribute name="message">
                                    <!-- strip the namespace if any -->
                                    <xsl:choose>
                                        <xsl:when test = "contains(wsdl:input/@message, ':')">
                                            <xsl:value-of select="substring-after(wsdl:input/@message, ':')" />
                                        </xsl:when>
                                        <xsl:otherwise>
                                            <xsl:value-of select="wsdl:input/@message" />
                                        </xsl:otherwise>
                                    </xsl:choose>
                                </xsl:attribute>
                            </input>
                        </xsl:if>

                        <xsl:if test="wsdl:output">
                            <output>
                                <xsl:attribute name="message">
                                    <!-- strip the namespace if any -->
                                    <xsl:choose>
                                        <xsl:when test = "contains(wsdl:output/@message, ':')">
                                            <xsl:value-of select="substring-after(wsdl:output/@message, ':')" />
                                        </xsl:when>
                                        <xsl:otherwise>
                                            <xsl:value-of select="wsdl:output/@message" />
                                        </xsl:otherwise>
                                    </xsl:choose>
                                </xsl:attribute>
                            </output>
                        </xsl:if>

                        <xsl:if test="wsdl:documentation">
                            <documentation>
                                <xsl:value-of select="."/>
                            </documentation>
                        </xsl:if>

                    </operation>
                </xsl:for-each>

            </portType>
        </xsl:for-each>

        <!--
        =========================================================
        colect what we need from messages node[s]
        =========================================================
        -->
        <xsl:for-each  select="wsdl:message">
            <message>

                <xsl:attribute name="name">
                    <xsl:value-of select="@name" />
                </xsl:attribute>


                <!--
                    collect the parts - only the first part used  and we support only the element attribute
                    type attribute is ignored.
                    we add it as an atribute to the Message element
                -->
                <xsl:if test="wsdl:part">
                    <xsl:attribute name="element">
                        <xsl:choose>
                            <!-- strip the namespace if any -->
                            <xsl:when test = "contains(wsdl:part/@element, ':')">
                                <xsl:value-of select="substring-after(wsdl:part/@element, ':')" />
                            </xsl:when>
                            <xsl:otherwise>
                                <xsl:value-of select="wsdl:part/@element" />
                            </xsl:otherwise>
                        </xsl:choose>
                    </xsl:attribute>
                   </xsl:if>
            </message>
        </xsl:for-each>

        <!--
        =========================================================
        colect what we need from type node
        =========================================================
        -->
        <xsl:for-each  select="wsdl:types">
            <types>
                <schema>
                    <xsl:for-each  select="s:schema/s:element">
                        <element>
                            <xsl:attribute name="name">
                                <xsl:value-of select="@name" />
                            </xsl:attribute>

                            <xsl:if test="@type">
                                <xsl:attribute name="type">
                                    <!-- strip the namespace if any -->
                                    <xsl:choose>
                                        <xsl:when test = "contains(@type, ':')">
                                            <xsl:value-of select="substring-after(@type, ':')" />
                                        </xsl:when>
                                        <xsl:otherwise>
                                            <xsl:value-of select="@type" />
                                        </xsl:otherwise>
                                    </xsl:choose>
                                </xsl:attribute>
                             </xsl:if>

                            <xsl:if test="s:complexType/s:sequence/s:element">
                                <complexType>
                                    <sequence>
                                            <xsl:for-each  select="s:complexType/s:sequence/s:element">
                                                <element>
                                                    <xsl:attribute name="name">
                                                        <xsl:value-of select="@name" />
                                                    </xsl:attribute>
                                                    <xsl:if test="@type">
                                                        <!-- strip the namespace if any -->
                                                        <xsl:attribute name="type">
                                                            <xsl:choose>
                                                                <xsl:when test = "contains(@type, ':')">
                                                                    <xsl:value-of select="substring-after(@type, ':')" />
                                                                </xsl:when>
                                                                <xsl:otherwise>
                                                                    <xsl:value-of select="@type" />
                                                                </xsl:otherwise>
                                                            </xsl:choose>
                                                        </xsl:attribute>
                                                    </xsl:if>
                                                </element>
                                            </xsl:for-each>
                                    </sequence>
                                </complexType>
                            </xsl:if>

                        </element>
                    </xsl:for-each>
                </schema>
            </types>
        </xsl:for-each>

        <!--
        =========================================================
        get top level documentation node
            in case there are no services (just portTypes) this will be used
        =========================================================
        -->
        <xsl:for-each select="wsdl:documentation">
            <documentation>
                <xsl:value-of select="."/>
            </documentation>
        </xsl:for-each>

    </xsl:template>

<xsl:template match="text()" />
</xsl:stylesheet>